QML Introduction



  • 参考视频:Introduction to Qt - Intro to QML {tutorial}

    主要功能

    • 点击Sender,Receiver会变颜色,然后计数+1
    • 按+-键,Sender和Receiver会变大变小,按Esc键会复原

    源码

    Background.qml

    import QtQuick 2.11
    
    BackgroundForm {
        property Circle target: null
        focus: true
    
        Keys.onPressed: {
            if(event.key === Qt.Key_Plus || event.key === Qt.Key_Equal){
                target.width += 10
                target.visible = true
            }
            if(event.key === Qt.Key_Minus || event.key === Qt.Key_Underscore){
                if(target.width>0){
                    target.width -= 10
                    target.visible = true
                }else{
                    target.visible = false
                }
    
            }
            if(event.key === Qt.Key_Escape){
                target.width = 200
            }
        }
    }
    
    

    BackgroundForm.ui.qml

    import QtQuick 2.11
    
    Item {
        width: 400
        height: 400
    
        Rectangle {
            id: rectangle
            gradient: Gradient {
                GradientStop {
                    position: 0
                    color: "#80d5f6"
                }
    
                GradientStop {
                    position: 1
                    color: "#000000"
                }
            }
            anchors.fill: parent
        }
    }
    
    

    Circle.qml

    import QtQuick 2.11
    
    CircleForm {
    }
    
    

    CircleForm.ui.qml

    import QtQuick 2.11
    
    Item {
        width: 200
        height: 200
        property alias buttonColor: button.color
        property alias displayText: display.text
    
        Rectangle {
            id: button
            width: 200
            height: 200
            color: "#ff0000"
            radius: width * 0.5
            anchors.fill: parent
    
            Text {
                id: display
                x: 176
                y: 194
                text: qsTr("Hello Qt")
                anchors.horizontalCenter: parent.horizontalCenter
                anchors.verticalCenter: parent.verticalCenter
                font.family: "Times New Roman"
                font.pixelSize: 24
            }
        }
    }
    
    

    Receiver.qml

    import QtQuick 2.11
    Circle {
        id: receiveButton
    
        function receive(value){
            displayText = value
            clicknotify.running = true
        }
    
        SequentialAnimation on buttonColor {
            id: clicknotify
            running: false
    
    
            ColorAnimation {
                from: "red"
                to: "blue"
                duration: 500
            }
    
            ColorAnimation {
                from: "blue"
                to: "red"
                duration: 500
            }
        }
    }
    
    

    Sender.qml

    import QtQuick 2.11
    
    Circle {
        id: sendButton
    
        property int counter: 0
        property Receiver target: null
    
        signal send(string value)
        onTargetChanged: send.connect(target.receive)
    
        MouseArea{
            anchors.fill: parent
    
            onClicked: {
                counter++
                parent.send(counter)
            }
    
            onPressed: {
                parent.buttonColor = "green"
            }
            onReleased: {
                parent.buttonColor = "blue"
            }
        }
    }
    
    

    main.qml

    import QtQuick 2.11
    import QtQuick.Window 2.11
    
    Window {
        visible: true
        width: 640
        height: 480
        title: qsTr("QML Introduction")
    
        Background {
            id: background
            anchors.fill: parent
            target: sender
            Sender {
                id: sender
                y: 214
                displayText: "Sender"
                anchors.verticalCenterOffset: 0
                anchors.left: parent.left
                anchors.leftMargin: 50
                anchors.verticalCenter: parent.verticalCenter
                target: receiver
            }
    
            Receiver {
                id: receiver
                x: 532
                y: 240
                displayText: "Receiver"
                anchors.right: parent.right
                anchors.rightMargin: 50
                anchors.verticalCenter: parent.verticalCenter
                width: sender.width
                visible: sender.visible
            }
        }
    }
    
    

    截图

    最后的运行效果

    image

    自己做的时候留下的部分截图

    image
    image
    image

    思考与总结

    我刚刚看到视频中做Background和Circle组件时,感到非常奇怪,为什么要用一个Item,而不直接使用Rectangle呢?后来看到,先把这两个组件做好,最后进行组装,特别好用。用js做的一些简单逻辑也非常方便。

    GitHub: https://github.com/PikachuHy/qml-demo/tree/master/qml-introduction


Log in to reply
 

走马观花

最近的回复

  • C

    Qt for MCU需要商业授权的

    read more
  • Qt for MCUs

    搭建Qt for MCUs PC端开发环境。qt for mcus提供了一个完整的图形框架和工具包,包含了在MCUs上设计、开发和部署gui所需的一切。它允许您在裸机或实时操作系统上运行应用程序。

    先决条件

    开发主机环境支持仅限于Windows 10

    MSVC compiler v19.16 (Visual Studio 2017 15.9.9 or newer) x64

    CMake v3.13 or newer (you can install it using the Qt Online installer) x64

    使用Qt联机安装程序安装Qt for MCUs,该安装程序可通过Qt帐户下载

    安装Qt 5.14和Qt Creator 4.11 or higher

    安装链接

    › Qt: https://account.qt.io/downloads
    › CMake: https://cmake.org/download/
    › Python 2.7 32-bit: https://www.python.org/downloads/release/python-2716/
    › Arm GCC: https://developer.arm.com/tools-and-software/open-source-software/developer-tools/gnutoolchain/gnu-rm/downloads
    › J-Link Software Pack: https://www.segger.com/downloads/jlink/JLink_Windows.exe
    › J-Link OpenSDA Firmware: https://www.segger.com/downloads/jlink/OpenSDA_MIMXRT1050-EVKHyperflash
    › STM32CubeProgrammer: https://www.st.com/en/development-tools/stm32cubeprog.html
    › STM32 ST-LINK Utility: https://www.st.com/en/development-tools/stsw-link004.html​​​​​​​

    Qt Creator设置 启用Qt Creator插件 选择“帮助>关于插件”,然后从列表中选择“MCU支持(实验性)”插件,重新启动Qt Creator以应用更改
    替代文字 为MCU创建Qt工具包

    选择工具>选项>设备>MCU

    选择Qt for MCUs-Desktop 32bpp作为目标

    如果尚未设置,请提供Qt for MCUs安装目录的路径。

    单击Apply应用。

    替代文字

    替代文字
    替代文字

    注意:

    编译器要选X64,Qt版本要选64bit,CMake Tool选x64

    打开恒温器项目demo

    选择文件>打开文件或项目。。。

    打开CMakefiles.txt文件来自thermo文件夹的文件。

    选择Qt作为MCU-桌面32bpp套件。

    单击“配置项目”以完成。

    替代文字

    问题

    开发主机环境支持仅限于Windows 10

    C++编译失败,文本大字体.pixelSize.

    文本类型无法正确呈现需要复杂文本布局的unicode序列。对复杂文本使用StaticText

    read more
  • H

    hi 有问题请教你,方便加个联系方式吗

    read more
  • boost.asio是一个很棒的网络库,这回儿我也开始系统地学习起来了。想想当年接触boost,也有八年多了。这次开始接触boost,觉得既熟悉又陌生。熟悉的是小写字母+下划线的命名方式、晦涩的模板、很慢的编译速度以及较大的程序体积,陌生的是asio的各种概念:io服务、接收器、套接字等等:我之前对网络编程不是非常了解。

    于是根据我的理解,参考《Boost.Asio C++网络编程》实现了这样一个简单的客户端和服务端通信的例子,例子非常简单,还不完善,但是幸运的是,可以在本机上互通了。
    下面是客户端的代码:

    #include <iostream> #include <boost/asio.hpp> #include <boost/proto/detail/ignore_unused.hpp> using namespace std; using namespace boost::asio; using namespace boost::system; using namespace boost::proto::detail;// 提供ignore_unused方法 void writeHandler( const boost::system::error_code& ec, size_t bytesTransferred ) { if ( ec ) { cout << "Write data error, code: " << ec.value( ) << "transferred: " << bytesTransferred << endl; } else { cout << "OK! " << bytesTransferred << "bytes written. " << endl; } } int main(int argc, char *argv[]) { ignore_unused( argc ); ignore_unused( argv ); io_service service; ip::tcp::socket sock( service ); ip::tcp::endpoint ep( ip::address::from_string( "127.0.0.1" ), 6545 ); boost::system::error_code ec; sock.connect( ep, ec ); if ( ec ) { cout << "Connect error, code: " << ec.value( ) << ", We will exit." << endl; return ec.value( ); } else { char buf[1024] = "Hello world!"; sock.async_write_some( buffer( buf ), writeHandler ); sock.close( ); } return service.run( ); }

    下面是服务端的代码:

    #include <iostream> #include <boost/asio.hpp> #include <boost/proto/detail/ignore_unused.hpp> using namespace std; using namespace boost::asio; using namespace boost::system; using namespace boost::proto::detail;// 提供ignore_unused方法 void acceptHandle( const boost::system::error_code& code ) { cout << "Accepted." << endl; } int main(int argc, char *argv[]) { ignore_unused( argc ); ignore_unused( argv ); io_service service; ip::tcp::endpoint ep( ip::address::from_string( "127.0.0.1" ), 6545 ); boost::system::error_code ec; ip::tcp::socket sock( service ); ip::tcp::acceptor acceptor( service, ep ); acceptor.async_accept( sock, acceptHandle ); if ( ec ) { cout << "There is an error in server. code: " << ec.value( ) << endl; } return service.run( );// 阻塞运行 }

    运行结果是这样的:
    78448d7b-b3ae-42fc-9e2e-4dd2fbdac2c2-image.png

    我对boost.asio中几个概念的理解:

    io_service,这就是一个类似事件循环的东西,它为io设备提供服务,故名。不管是套接字、文件还是串口设备,都要使用它的服务。它的run()函数相当于启动了一个事件循环。一旦有消息了,即进行响应。这也是实现异步编程的重要基础。 socket,这个类则是套接字,可以处理TCP或者是UDP请求。有同步以及异步的处理方式,也有带异常以及不带异常的处理方式。 acceptor,接收器,仅仅是服务端使用。相当于其余框架中的listener,作接收用的。

    比较浅显,如果有不当之处,敬请指正。

    read more

关注我们

微博
QQ群